current community

your communities

more stack exchange communities

Stack Exchange
tour help
stack overflow careers
Take the 2-minute tour ×
Stack Overflow is a question and answer site for professional and enthusiast programmers. It's 100% free, no registration required.
up vote 0 down vote favorite

So, I've got this basic text file called prev_batch.cfg that I want a batch script to read. prev_batch.cfg is a single line of text, but tokens are delimited with a comma. It looks something like:

apples,oranges,bananas,grapes,strawberries

I'd like each of those tokens to go into a specific variable I have setup in a for loop. The problem is only the first variable gets set within the loop. Nothing else. I want all the variables to be set to the tokens found within the delimited list in the .cfg file.

Here is what my batch script looks like up until the close of the FOR loop:

@ECHO ON

setlocal EnableDelayedExpansion

SET JOB=%1
SET USER=%2
SET ASSETROOT=%3

:: Read all the arguments for this batch script from external text file
FOR /F "delims=," %%a IN (%ASSETROOT%\users\%USER%\%JOB%\prev_batch.cfg) do (
SET JOB=%%a
SET USER=%%b
SET TEMPLATE=%%c
SET ASSETROOT=%%d
SET SHAREADDR=%%e
SET SHARENAME=%%f
SET SHAREDRIVE=%%g
SET SHAREUSER=%%h
SET SHAREPASS=%%i
)

I'm running the batch file and passing three command line parameters into it. I'm outputting the echo of the batch when it runs to a log file. And this is what I'm seeing:

C:\Windows\system32>setlocal EnableDelayedExpansion 

C:\Windows\system32>SET JOB=99D0FAA9-22B8-4FE7-9321-21F5587E8177 

C:\Windows\system32>SET USER=10

C:\Windows\system32>SET ASSETROOT=C:\app 

C:\Windows\system32>FOR /F "delims=," %a IN (C:\app\users\10\99D0FAA9-22B8-4FE7-9321-21F5587E8177\prev_batch.cfg) do (
SET JOB=%a  
 SET USER=%b  
 SET TEMPLATE=%c  
 SET ASSETROOT=%d  
 SET SHAREADDR=%e  
 SET SHARENAME=%f  
 SET SHAREDRIVE=%g  
 SET SHAREUSER=%h  
 SET SHAREPASS=%i 
) 

C:\Windows\system32>(
SET JOB=99D0FAA9-22B8-4FE7-9321-21F5587E8177  
 SET USER=%b 
 SET TEMPLATE=%c  
 SET ASSETROOT=%d  
 SET SHAREADDR=%e  
 SET SHARENAME=%f  
 SET SHAREDRIVE=%g  
 SET SHAREUSER=%h  
 SET SHAREPASS=%i 
)
share|improve this question

3 Answers 3

up vote 2 down vote accepted

try this:

FOR /F "usebackq tokens=1-9 delims=," %%a IN ("%ASSETROOT%\users\%USER%\%JOB%\prev_batch.cfg") do (
SET JOB=%%a
SET USER=%%b
SET TEMPLATE=%%c
SET ASSETROOT=%%d
SET SHAREADDR=%%e
SET SHARENAME=%%f
SET SHAREDRIVE=%%g
SET SHAREUSER=%%h
SET SHAREPASS=%%i
)

[addition by PW in response to supplementary question]

SET init=Y
SET "fields=JOB USER TEMPLATE ASSETROOT SHAREADDR SHARENAME SHAREDRIVE SHAREUSER SHAREPASS"

FOR /F "usebackq" %%a IN ("%ASSETROOT%\users\%USER%\%JOB%\prev_batch.cfg") do (
 IF DEFINED init FOR %%i IN (%fields%) DO SET "%%i="
 SET init=Y
 FOR %%i IN (%fields%) DO IF DEFINED init IF NOT DEFINED %%i SET "%%i=%%a"&SET "init="
)

To read from sequential lines, the tokens and delims clauses are not required since there's only one string on each line BUT that one string needs to be applied to various variables.

Complicating the matter is the fact that variables that need to be set are used in the filename being read to set them.

Hence, the init flag is set non-empty initially; the variables are set once the first data line is read.

The next not-yet-set target variable is then set and the init flag cleared to ensure only one variable is set per line read.

share|improve this answer
    
This worked perfectly, thanks. Quick question: what would the for loop look like if the values of the variables were on separate lines in the .cfg file rather than delimited by commas? –  ariestav Jun 12 '13 at 5:03
    
if the variables are on separate lines you do not need tokens. In this case you can read the variables successively. –  Endoro Jun 12 '13 at 6:24
    
Not the case! Think again - if the items are on separate lines, the first will be applied to %%a and no others allotted. The file would thenbe read and the last line would be the element applied to JOB. I've edited Endoro's solution in response to this supplemental question... –  Magoo Jun 12 '13 at 9:15
    
@Peter the question was what would the for loop look like if the values of the variables were on separate lines and my answer concerning the for loop was right :) , nevertheless thanks for your remarks .... –  Endoro Jun 12 '13 at 10:25
up vote 0 down vote

okay, I like batch files and this one had me going for a while. You've told it that you only want %%a so that's what you're getting. As Endoro said (I was typing the same answer when he posted), including the "tokens" keyword tells it which tokens you want. Token %%a, obviously is the first, but by also telling the command processor that you want tokens 1-9 it separates and assigns them to next alphabetical 'variable'. And in this case, usebackq is superfluous

share|improve this answer
    
The usebackq was essential to it functioning. –  ariestav Jun 12 '13 at 5:01
    
@AlJones the OP sets three parameters of his first for loop via command line parameters. are you sure that there is no space in it? –  Endoro Jun 12 '13 at 6:59
    
Something about this question has made me hungry... The point is that usebackq IS necessary, but only because Endoro introduced the notion of quoting the filename - certainly a sensible measure. Could whoever voted this response down please reverse their action - this is a polite area which appreciates contributions, not like say Delphi, where there's a mutual self-appreciation society routinely downvoting contributions from the self-appointed ruling clique. –  Magoo Jun 12 '13 at 9:23
    
@endoro - :) Okay, I stand corrected for logical reasons given. Wasn't me who voted it down, I wouldn't unless the information was completely incorrect. Good, informative discussion. –  Al Jones Jun 12 '13 at 16:39
up vote 0 down vote

There is another approach to solve this problem via an array of variable names. This method have the advantage that any modification to the list of variables (the number of variables, their names, their positions, etc) is made in a very easy way modifing just one line in the Batch file.

@echo off
setlocal EnableDelayedExpansion

rem Define the list of variable names
set variables=JOB USER TEMPLATE ASSETROOT SHAREADDR SHARENAME SHAREDRIVE SHAREUSER SHAREPASS

rem Convert the list into an array of variable names
set i=0
for %%a in (%variables%) do (
   set /A i+=1
   set variable[!i!]=%%a
)
set numVariables=%i%

:: Read all the arguments for this batch script from external text file

rem Version 1: Single line of text, tokens delimited with comma
set i=0
for /F "delims=" %%a in (%ASSETROOT%\users\%USER%\%JOB%\prev_batch.cfg) do (
   for %%b in (%%a) do (
      set /A i+=1
      for %%i in (!i!) do set !variable[%%i]!=%%b
   )
)

rem Version 2: Values of the variables on separate lines
set i=0
for /F "delims=" %%a in (%ASSETROOT%\users\%USER%\%JOB%\prev_batch.cfg) do (
   set /A i+=1
   for %%i in (!i!) do set !variable[%%i]!=%%a
)

rem Display values of all variables
for %%i in (1,1,%numVariables%) do (
   for %%v in (!variable[%%i]!) do echo %%v = !%%v!
)

In the first version, the line of the file is read in %%a replaceable parameter and then processed in a for command this way:

for %%b in (%%a) do (

For example:

for %%b in (apples,oranges,bananas,grapes,strawberries) do (

Because standard Batch delimiters are space, comma, semicolon and equal-signs, the values in the list are processed one by one in the for (with NO /F option). This method allows to easily separate a list of values in individual tokens in a regular for command, but works only with the indicated delimiters.

share|improve this answer

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.