batch variable nested into a batch variable

Excuse me. Sometimes I think I don't really understand the questions (perhaps because my mother tongue is not English).

In your question you said you want to replace "the text after 'X' and before 'Open file' in mypath variable... by 'foo'" and even you said "text which is currently "Dashboard" into mypath variable is not a static text. It can be "Dboard", or anything", but in your code and posterior comments in the answers it seems that you just want to change the strings "Dashboard" or "Dboard" by "foo". This confuses me.

Anyway, this is my solution to your question (not to your comments).

@echo off
setlocal EnableDelayedExpansion

SET mypath=Y:\SUT\ISTQB\Board Airport\X\Dashboard\Open file

rem Get the text after 'X' and before 'Open file'
set auxPath=%mypath%
set enclosed=
set text=
:nextPart
   for /F "tokens=1* delims=\" %%a in ("%auxPath%") do (
      if "%%a" equ "Open file" (set enclosed=) else (
      if defined enclosed (set "text=!text!\%%a") else (
      if "%%a" equ "X" (set enclosed=1)
      ))
      set "auxPath=%%b"
   )
if defined auxPath goto nextPart
set text=%text:~1%

rem Replace that text by "foo"
call :Change "%text%"
goto :EOF

:Change
SET mypath=!mypath:\%~1\=\foo\!
ECHO %mypath%
exit /B

For example, the output of previous program is this:

Y:\SUT\ISTQB\Board Airport\X\foo\Open file

But if mypath variable would be this:

Y:\SUT\ISTQB\Board Airport\X\One\Two three\Open file

... the output would be this:

Y:\SUT\ISTQB\Board Airport\X\foo\Open file

... that precisely solves your request.

        @echo off
        SET mypath=Y:\SUT\ISTQB\Board Airport\X\Dashboard\Open file

        if /i "%~1"=="Dashboard" goto :label 
        if /i "%~1"=="Dboard" goto :label 

        goto :eof
        :label
        rem set temp_var=%~1
        rem call SET mypath=%%mypath:%temp_var%=foo%%
        rem echo %mypath%
   setlocal enabledelayedexpansion 
        set mypath=!mypath:%~1=foo!
        ECHO !mypath!
    endlocal

Could you try this?

Your problem was the search/replace using a %1 :-
SET mypath=%mypath:\%1\=foo% has too many % characters upsetting the syntax a bit.

This answer was to use EnableDelayedExpansion to take advantage of the ! syntax, but beware the %mypath% variable will lose its value after endlocal - it only keeps its value within the setlocal block.

One way around this is to write the SET command to a temporary batch file, and call it after the local block :

setlocal EnableDelayedExpansion
  SET mypath=!mypath:%1=foo!
     rem  Create a batch file to perform SET later : 
  echo @SET mypath=%mypath% > "%TEMP%\setmyvar.bat"
endlocal

   rem  Now use the batch file to set the variable :
call "%TEMP%\setmyvar.bat"
ECHO %mypath%

If there's a more elegant way to do this, please let us know :)