Tell me more ×
Stack Overflow is a question and answer site for professional and enthusiast programmers. It's 100% free, no registration required.
up vote 0 down vote favorite

I have a text file contains nearly 20 lines wanted to search a string in file and print next 5th line in file using autoit, any one can help me to solve this

#include <File.au3>
#include <array.au3>


$file = @ScriptDir & "\file.txt"
$search = "str"

If FileExists($file) Then
    $contents = FileRead($file)
    If @error Then
        MsgBox(0, 'File Error', $file & ' could not be read.')
    Else
        For $i = 1 To $count
            If StringInStr($contents, $search) Then        
                MsgBox(0, 'Positive', $file & ' does contain the text "' & $search & '"')
            Else
                MsgBox(0, 'Negative', $file & ' does NOT contain the text "' & $search & '"')
            EndIf
        Next
    EndIf
EndIf
share|improve this question
add comment (requires an account with 50 reputation)

1 Answer

up vote 2 down vote accepted

This reads the text file until the search string is found and then writes the next 5 lines to STDOUT:

#include <File.au3>
#include <Array.au3>


Global $file = @ScriptDir & "\file.txt", $search = "str"
Global $iLine = 0, $sLine = ''
Global $hFile = FileOpen($file)
If $hFile = -1 Then 
    MsgBox(0,'ERROR','Unable to open file for reading.')
    Exit 1
EndIf

; find the line that has the search string
While 1
    $iLine += 1
    $sLine = FileReadLine($hFile)
    If @error = -1 Then ExitLoop

    ; $search found in the line, now write the next 5 lines to STDOUT
    If StringInStr($sLine, $search)And Not $iValid  Then    
        For $i = $iLine+1 To $iLine+5
            ConsoleWrite($i & ':' & FileReadLine($hFile, $i) & @CRLF)
        Next
        ExitLoop
    EndIf
WEnd
FileClose($hFile)

Edit

Due to Matt's argument here's a 2nd version of the loop that doesn't use the "line" parameter for FileReadLine.

#include <File.au3>
#include <Array.au3>


Global $file = @ScriptDir & "\file.txt", $search = "str"
Global $iLine = 0, $sLine = '', $iValid = 0
Global $hFile = FileOpen($file)
If $hFile = -1 Then 
    MsgBox(0,'ERROR','Unable to open file for reading.')
    Exit 1
EndIf

; find the line that has the search string
While 1
    $iLine += 1
    $sLine = FileReadLine($hFile)
    If @error = -1 Then ExitLoop

    ; test the line for the $search string until the flag $iValid is set
    If StringInStr($sLine, $search) And Not $iValid Then
        $iValid = 1
        ContinueLoop
    EndIf

    If $iValid Then
        $iValid += 1
        ConsoleWrite($iLine & ':' & $sLine & @CRLF)
        If $iValid > 5 Then ExitLoop
    EndIf
WEnd
FileClose($hFile)

You won't note much difference between those two versions of the script, unless you are reading a file with 10k+ lines and the lines you are looking for are in the last quarter of that file but it surely is a good idea to prevent possible performance issues.

share|improve this answer
Its working thanks :) – passionTime 22 hours ago
1  
Using FileReadLine with its second parameter incrementing by one like in the For...Next loop above is not a good idea. You won't notice performance in a small script like this but just something to bear in mind. – Matt 18 hours ago
@Matt: Yes you got a point there. I will edit my answer and add a different solution. – mrt 41 mins ago
add comment (requires an account with 50 reputation)

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.