How to add an array to an array using VBScript

It's hard to troubleshoot without test data provided, but going by what you're saying, that you want to "add an array to each "row" of an existing array", this is not what I see happening in your code. In fact, you're adding an element of one array as an element of another. If you want to add the whole array, and I think you do, you'd do something like:

arrComm(j,7) = newMembers

Because you want all the members in there, right, not just the last one? (Not to mention you've post-incremented y in the loop, so in fact you're not even getting the last one.) And then, of course, in your output code you'd have to interrogate the ubounds within newMembers, since it's dynamically-created.

This is one of those situations where the complexity almost requires you to break the code off into a standalone runable page with dummy data in order to test, and especially to help us see the problem.

Adding sample code to dump resulting array:

dim tempMembers
' pick a Members element for testing
tempMembers = arrComm(0,7)
' dump the array
dim a,b
for a = 0 to ubound(tempMembers,1)
    for b = 0 to ubound(tempMembers,2)
        response.write (tempMembers(a,b) & ",")
    next
    response.write "<br />"
next

What we really need is some sample inbound data. I was able to get the code to run with the following, but obviously it doesn't reflect reality:

dim arrMembers()
dim arrComm()
ReDim Preserve arrComm (1,1)
ReDim Preserve arrMembers (1,8)
arrComm (0,0) = "target"
arrMembers (0,0) = "target"

Could you flesh that out to reflect what real data looks like? One or two rows with all the dimensions filled would be enough.

Full working example based on some of your test data:

dim arrMembers()
dim arrComm()
ReDim Preserve arrComm (2,7)
ReDim Preserve arrMembers (2,8)
arrComm (0,0) = "454-45-45"
arrComm (0,1) = "45345-3454"
arrComm (0,2) = "FIN"
arrComm (0,3) = "Elected"
arrComm (0,4) = "Finance Committee"
arrComm (0,5) = "Details"
arrComm (0,6) = "More Details"
arrComm (1,0) = "343-343-3"
arrComm (1,1) = "343-944244"
arrComm (1,2) = "COM"
arrComm (1,3) = "Appointed"
arrComm (1,4) = "Comm Committee"
arrComm (1,5) = "Details"
arrComm (1,6) = "More Details"
'
arrMembers (0,0) = "454-45-45"
arrMembers (0,1) = "John"
arrMembers (0,2) = "S"
arrMembers (0,3) = "Smith"
arrMembers (0,4) = "Chair"
arrMembers (0,5) = "2003"
arrMembers (0,6) = "2005"
'
arrMembers (1,0) = "454-45-45"
arrMembers (1,1) = "Sara"
arrMembers (1,2) = "T"
arrMembers (1,3) = "Jones"
arrMembers (1,4) = "Chair"
arrMembers (1,5) = "2012"
arrMembers (1,6) = "2013"
' non-match member
arrMembers (2,0) = "343-343-3"
arrMembers (2,1) = "Joe"
arrMembers (2,2) = "T"
arrMembers (2,3) = "Schmoe"
arrMembers (2,4) = "Chair"
arrMembers (2,5) = "2012"
arrMembers (2,6) = "2013"

ReDim Preserve arrComm(UBound(arrComm), 7)

'Loop through Committee Array and add Members Array 
Dim newMembers()

For j = 0 to UBound(arrComm)
'create a new array out of Members for each committee
 cmt_key = arrComm(j,0)

     'First find count of Members array that matches committee  
     y=0
     For s = 0 to UBound(arrMembers)
        If arrMembers(s,0) = cmt_key Then
        y=y+1
        End If  
     Next


     'Next build new array only with those members that match committee

     Redim newMembers(y,8)

     'Now loop through Original Members Array and add to New Members Array
     y=0
     For s = 0 to UBound(arrMembers)
        If arrMembers(s,0) = cmt_key Then
            newMembers(y,0) = arrMembers(s,0)
            newMembers(y,1) = arrMembers(s,1)
            newMembers(y,2) = arrMembers(s,2)
            newMembers(y,3) = arrMembers(s,3)
            newMembers(y,4) = arrMembers(s,4)
            newMembers(y,5) = arrMembers(s,5)
            newMembers(y,6) = arrMembers(s,6)
            newMembers(y,7) = arrMembers(s,7)
            newMembers(y,8) = arrMembers(s,8)
            y=y+1


        End If  
     Next



     'Now finally add newly created members array to Committee array

     arrComm(j,7) = newMembers



Next
'response.write (arrComm(0,7)(0,0))
dim tempMembers
' pick a Members element for testing
tempMembers = arrComm(0,7)
response.write (ubound(tempMembers,1) & " | " & ubound(tempMembers,2) & "<br />")
' dump the array
dim a,b
for a = 0 to ubound(tempMembers,1)-1
    for b = 0 to ubound(tempMembers,2)-1
        response.write (tempMembers(a,b) & ",")
    next
    response.write "<br />"
next