Tell me more ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.
up vote 8 down vote favorite
1

I often find myself in situations where I, for example, need to build a table for some expression, but want to set the number of points rather then the step size, so the code ends up looking like this

lower = 0.2;
upper = Pi^2;
points = 100;
Table[Sin[x], {x, lower, upper, (upper - lower)/(points - 1)}] // ListPlot

I think that the typical Table syntax is much nicer in cases where we want to set the stepsize, but would much rather prefer to just think of the iteration specifications to be of the form {var,min,max,num} in these cases. Initially I though I would to this by just defining a function that takes this other iteration specification and returns the traditional equivalent, but since Table has holdall, you'd need to wrap everything in Evaluate which isn't pretty either example:

myIter[L_]:={L[[1]],L[[2]],L[[3]],(L[[3]]-L[[2]])/L[[4]]}
Table[Sin[x], Evaluate@myIter[{x, 0.2, Pi^2, 100}]] // ListPlot

So to get around this I added a pattern to modify the way Table is called if the second argument was wrapped in linIter:

linIter /: Table[exp_, iterator_linIter] := Table[exp, Evaluate@myIter[List @@ iterator]]
Table[Sin[x], linIter[x, 0.2, Pi^2, 100]] // ListPlot

This then allows me to have somewhat nice syntax to specify a new iterator.

So my questions are

  • Whether others have a more elegant way of implementing this, that allows one to call the expression with multiple iterators mixing step size and number based?
  • What capabilities of Table I might possibly be losing by calling it this way?
  • Is it possible to retain the syntax highlighting of Table while doing this?
  • Also I'd appreciate general feedback. Am I committing blasphemy by messing with the call syntax for a built-in, or is would you easily get the intention if you where reading though some code that relied on this type of tricks to sort of have custom iterators?
share|improve this question

4 Answers

up vote 9 down vote accepted

You're not committing a blasphemy. In fact, you're defining an upvalue to your own symbol, so you're in the safe zone. I think your idea of using upvalues was a good one.

Alternatives are, to define your own parsing function such as

SetAttributes[it, HoldFirst];
it[Table[expr_, {var_, start_, end_, num_Integer}]]:=
    Table[expr, Evaluate@{var, start, end, (end-start)/(num-1)}]

so when you do the following you get what you want

Table[something[x], {x, 0, 10, 23}]//it

This could be extended to multiple iterator types. For example, doing the following

iterator["numpoints"]=Function[,it[##],HoldAll];

you can now do

Table[something[x], {x, 0, 10, 23}]//iterator["numPoints"]

and extend it the same way.

You could also define a myTable function that calls table and accepts an option of the iterator type.

The possible con of your original solution is the loss of the syntax highlighting. Perhaps it's not ideal but you could change it from

myIter[L_]:={L[[1]],L[[2]],L[[3]],(L[[3]]-L[[2]])/L[[4]]}

to

myIter[st_, en_, num_]:=(Range[num]-1)(en-st)+st

and then use it

Table[sth, {x, myIter[0, 10, 12]}]

Check the function FindDivisions

share|improve this answer
up vote 6 down vote

For an approximate solution, out of the box we have:

Table[Sin[x], {x, FindDivisions[{lower,upper},nSteps]}]

It is possible to force FindDivisions to use a fixed sized delta as in:

FindDivisions[{1, 5, \[Pi]/2}, 3]

{0, [Pi]/2, [Pi], (3 [Pi])/2, 2 [Pi]}

As you can see, FindDivisions has quite a strong bias towards what it thinks are "nice" intervals.

Table[Sin[x], {x, FindDivisions[{1, 5, \[Pi]/2}, 3]}]

{0, 1, 0, -1, 0}

Hence the result may contain more or less intervals than requested, here 5 instead of 3. This effect is more evident when few intervals are required.

share|improve this answer
Table[Sin[x], {x, FindDivisions[{1, 5}, 3]}] gives {0, Sin[2], Sin[4], Sin[6]} — that's most probably not what was intended. @jVincent's code gives for Table[Sin[x], linIter[x, 1, 5, 3]] the result {Sin[1], Sin[7/3], Sin[11/3], Sin[5]} which is more likely what he wanted (although I would consider the three-element list {Sin[1], Sin[3], Sin[5]} a more reasonable result). – celtschk Jun 18 '12 at 16:07
@celtschk I agree, it is approximate and may not be optimal. – image_doctor Jun 18 '12 at 17:08
up vote 3 down vote

Rather than hacking Table, you could use the Table[expr,{i,{listOfIterates}}] syntax, as described in the documentation, e.g. Table[Sqrt[x], {x, {1, 4, 9, 16}}].

Image_doctor has already posted the FindDivisions[] case, which doesn't necessarily actually start and end at your min and max - it finds "nice" divisions of round numbers spanning the minimum and maximum.

You could instead use With and your custom function.

With[{iters = Range[lower,upper, (upper - lower)/(points - 1)]},
  Table[Sin[x],{x,iters}] ]

Here I am showing the explicit definition but you could also define an auxiliary function.

myIter[L_]:=Range[L[[2]],L[[3]],(L[[3]]-L[[2]])/L[[4]]]

or this version, which ensures that the input is of the correct form.

myIter[{expr_,min_?NumericQ,max_?NumericQ,pts_Integer}]:=Range[min,max,(max-min)/pts] 
(* shouldn't this be pts +1?*)

With[{iters = myIter[{whatever,0.2,Pi^2, 100},
  Table[Sin[x],{x,iters}] ]
share|improve this answer
up vote 1 down vote

You can modify Table itself, which is not necessarily Evil, but should be approached with respect. The more low-level and internally used a function is the greater chance for problems.

A number of functions use { } around a numeric argument to specify a different meaning, and you could implement that as follows:

Unprotect[Table]

Table[a_, b___, {x_, start_, end_, {n_}}, c___] := 
  Table[a, b, {x, start, end, (end - start)/(n - 1)}, c]

Protect[Table]

Now:

Table[Sin[x], {x, 0.2, Pi^2, {100}}] // ListPlot

Mathematica graphics

You can use mixed iterator types:

Table[
  Sin[x y] / y,
  {x, 0.2, Pi^2, {100}},
  {y, 0.2, Pi, 0.05}
] // ListPlot3D

Mathematica graphics

If you choose not to modify Table you can use a similar definition with a custom head in one of two ways. First:

SetAttributes[myTable, HoldAll]

SyntaxInformation[myTable] = 
  {"ArgumentsPattern" -> {_, {_, _, _, _}, ___}, 
   "LocalVariables"   -> {"Table", {2, \[Infinity]}}};

myTable[a_, b___, {x_, start_, end_, {n_}}, c___] := 
  myTable[a, b, {x, start, end, (end - start)/(n - 1)}, c]

myTable[else___] := Table[else]

And use myTable with the same syntax as above. Notice that syntax highlighting is provided for.
Second, using UpValues (as you did but extending the definition):

Table[a_, b___, linIter[x_, start_, end_, n_], c___] ^:= 
  Table[a, b, {x, start, end, (end - start)/(n - 1)}, c]

Mixed forms are usable:

Table[
  Sin[x y] / y,
  linIter[x, 0.2, Pi^2, 100],
  {y, 0.2, Pi, 0.05}
] // ListPlot3D

Mathematica graphics

However, syntax highlighting is not provided for.

In each method I gave the definition with bare patterns for simplicity; it would be wise to do type checking such as n_Integer?Positive in practice.

share|improve this answer

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.