Testing code with Debug.Assert

As of now I see one major problem with this...

You are not even testing with the optional parameter.

All else equal, you are reusing the same variable and make multiple OPERATE statements.

"Each of the tests is clearly split into three parts. The first part builds up the test data, the second part operates on that test data, and the third part checks the operation yielded the expected results." - Robert C. Martin, Clean Code, p.127

Following this advice, you might want to split your test into neat compartments as mentioned by @Marc-Andre

The only thing that I can see at first glance to show what the business rule is, is to do something like this

m_GlobalCode = "ABC"
result = GetEquivalentCode
Debug.Assert result = "ABC2013"

probably at the beginning.

I think this is exactly what the business rule is saying from my understanding of the information that you have given

you probably want to add something like this to follow it, just to be clear what the rule is.

m_GlobalCode = "AB"
result = GetEquivalentCode
Debug.Assert result = "AB"

These two pieces coupled together show the entire Business Rule.

if the input string starts with "ABC" then return "ABC2013" otherwise return the input

6 tests should clearly define the Business Rule

1. Input: "ABC"
2. Input: "AB"
3. Input: vbNullString
4. Input: {Random String not Starting with "ABC"}
5. Input: "DABC" Result: "DABC"
6. Input: "ABC5029DDD"

Number 5 shows that ABC must be at the beginning of the string

Numbers 1 & 6 shows what the Function is doing.

Numbers 2,3,4, & 5 show what happens when the ABC is not at the beginning

Ok so this is what I ended up doing.

I created an interface, called it ITestClass.cls:

Option Explicit

Public Sub RunAllTests()
End Sub

Then I created a new module, called Tests.bas:

Private AllTests As Collection
Option Explicit

Private Sub SetupTestClasses()

    Set AllTests = New Collection

    AllTests.Add New PricingModuleTests
    'AllTests.Add New xxxxxxxxxTests

End Sub

Public Sub Run()

    SetupTestClasses

    Dim testClass As ITestClass
    For Each testClass In AllTests
        testClass.RunAllTests
    Next

End Sub

And then I added a new class to implement the ITestClass interface:

Implements ITestClass
Option Explicit

Private Sub ITestClass_RunAllTests()

    CodeShouldBeAsSpecified
    AnyABCCodeShouldBecomeABC2013

    Debug.Print TypeName(Me) & " completed."

End Sub


Public Sub CodeShouldBeAsSpecified()

    'arrange
    Dim code As String
    code = "XYZ123"

    Dim expected As String
    expected = "XYZ123"

    Dim actual As String

    'act
    actual = ModuleBeingTested.GetEquivalentCode(code)

    'assert
    Debug.Assert expected = actual
    Debug.Print "CodeShouldBeAsSpecified: PASS"

End Sub

Public Sub AnyABCCodeShouldBecomeABC2013()

    'arrange        
    Dim code As String
    code = "ABC123"

    Dim expected As String
    expected = "ABC2013"

    Dim actual As String

    'act
    actual = ModuleBeingTested.GetEquivalentCode(code)

    'assert
    Debug.Assert expected = actual
    Debug.Print "AnyABCCodeShouldBecomeABC2013: PASS"

End Sub

Now this has the drawback that I had to make the GetEquivalentCode method Public when it could have really been Private to ModuleBeingTested, but now I have a little bit of a structure so that whenever I write a piece of testable code (the rest of the code has too many dependencies to be anywhere near testable), I can write a test for it and have all tests execute with a single call.

As you can see, properly defining what the rules are makes much fewer tests required.

Immediate pane:

Tests.Run
CodeShouldBeAsSpecified: PASS
AnyABCCodeShouldBecomeABC2013: PASS
PricingModuleTests completed.

If any test fails, it won't output a "FAIL", rather the debugger will break at the assertion that failed; I'm fine with that.