current community

your communities

more stack exchange communities

company blog
Stack Exchange Inbox Reputation and Badges
tour help
Dismiss
Announcing Stack Overflow Documentation

We started with Q&A. Technical documentation is next, and we need your help.

Whether you're a beginner or an experienced developer, you can contribute.

Sign up and start helping → Learn more about Documentation →
up vote 2 down vote favorite

Can anybody tell me how to push a duplicate element of an array to a new array? This is what I have till now, again I want to retain the duplicate elements into a new array. 

%seen = ();
@uniq = ();
foreach $item (@list) {
    unless ($seen{$item}) {
        $seen{$item} = 1;
        push(@uniq, $item);
    }
}
print "@unique\n";
share|improve this question
6  
Are you trying to find duplicates, as your text says, or are you trying to remove duplicates as your code says? – Flimzy Jul 11 '12 at 8:19
up vote 3 down vote accepted

If you're trying to find values that appear more than once:

my @seen;
my @dups = grep ++$seen{$_} == 2, @list;


@list = qw( foo bar baz foo foo moo bar );
  gives
@dups = qw( foo bar );

If you're trying to put the values that are only found once in @uniq and values that are found twice or more in @dups:

my %counts; 
++$counts{$_} for @list;

my (@uniq, @dups);
for (@list) {
   my $count = $counts{$_};
   push @uniq, $_ if $count == 1;
   push @dups, $_ if $count == 2;
}


@list = qw( foo bar baz foo foo moo bar );
  gives
@uniq = qw( baz moo );
@dups = qw( foo bar );

If you're trying to put the first instance of a value in @uniq and the second and subsequent values in @dups:

my (@uniq, @dups, %seen);
push @{ $seen{$_}++ ? \@dups : \@uniq }, $_ for @list;


@list = qw( foo bar baz foo foo moo bar );
  gives
@uniq = qw( foo bar baz moo );
@dups = qw( foo foo bar );
share|improve this answer
up vote 6 down vote

Always start your scripts with use strict; and use warnings;.

use strict ;
use warnings ;

my @list = ( 1 .. 10 , 2 , 5 , 6 ) ;

my %seen = ();
foreach my $item (@list) {
  $seen{$item}++ ;
}

my @uniq = grep { $seen{$_} == 1 } keys %seen ;
my @not_unique = grep { $seen{$_} > 1 } keys %seen ;

Simply count each occurrence of the elements in a hash and use a grep afterwards.

share|improve this answer
up vote 5 down vote

It's unclear what you're trying to accomplish... do you want to remove duplicates, or find them? Here's a solution for either:

To remove duplicates

use strict;
use warnings;

my @list = (1,2,3,4,5,6,1,2,3);

my %unique;
@unique{ @list } = ();
print join(',',sort keys %unique)."\n";

Output:

1,2,3,4,5,6

To grab only duplicates

use strict;
use warnings;

my @list = (1,2,3,4,5,6,1,2,3);

my %dupes;
%dupes = map { $_ => $dupes{$_}++ } @list;
delete @dupes{ grep { $dupes{$_} == 0 } keys %dupes };
print join(',',sort keys %dupes)."\n";

Output:

1,2,3

share|improve this answer
1  
sub uniq { my %seen; grep ! $seen{$_}++, @_ } will maintain the order of the list, as will sub dupe { my %seen; grep $seen{$_}++, @_ } – Zaid Jul 11 '12 at 10:54
    
@Zaid: A nice addition. Thanks! – Flimzy Jul 11 '12 at 16:23
up vote 3 down vote

Same logic as yours, but different statements.

use strict;
my @ar = (1,2,3,4,1,2);
my %ar = map { $_ ,  1 } @ar ;
my @ar1 = keys %ar;

print @ar1;

Also check this

share|improve this answer
    
Thank you everybody! – Pink Jul 11 '12 at 21:55
up vote 2 down vote

Eliminating duplicates is this simple: 

use List::MoreUtils qw<uniq>;

my @uniq = uniq @list;

Getting duplicates, requires a little more explicit Perl:

my %seen;
my @dups = grep { ++$seen{ '' . $_ } == 2 } @list;
share|improve this answer
up vote 1 down vote

You must always use strict and use warnings at the start of your programs, and declare all variables using my at their point of first use. In this case it would have shown you that you were addaing data to the array @uniq but displaying the contents of @unique.

This program will print a list of all unique data items, and a second list of data that has occurred twice or more

use strict;
use warnings;

my @list = qw/ a a a b b c /;

my %seen;
my @uniq;
my @multiple;

foreach my $item (@list) {
  if (not $seen{$item}++) {
    push @uniq, $item;
  }
  elsif ($seen{$item} == 2) {
    push @multiple, $item;
  }
}
print "Unique: @uniq\n";
print "Multiple: @multiple\n";
share|improve this answer

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.