Method refactoring in perl

First off, stuff like my @aFields = split(/~/, $phParams->{sFields}); is a sign of something gone awry. You've just deserialized $phParams from a JSON object, so why isn't this just stored in a normal array?

There is no need to write $i < scalar(@aFields), just write $i < @aFields.

I have some comments wrt. this snippet:

my $value = $aValues[$i];
if ($phFieldInfo->{value_displays}) {
    $value = @{$phFieldInfo->{value_displays}}[$value];
} elsif ($phFieldInfo->{value_keys}) {
    $value = @{$phFieldInfo->{value_keys}}[$value];
}

You should always use warnings; and use strict;. The above won't run without warnings if warnings are on because @{$phFieldInfo->{value_keys}}[$value] should be written ${$phFieldInfo->{value_keys}}[$value].

Also, the whole thing can be written much shorter:

my $value = ${$phFieldInfo->{value_displays}}[$aValues[$i]]
    || ${$phFieldInfo->{value_keys}}[$aValues[$i]]
    || $aValues[$i];

Note: this isn't functionally identical with the original code, since I'm assuming that array refs at the keys value_displays and value_keys exists.

This essentially means "pick the first trueish value". Note that values like undef, 0 or the empty string won't be picked. If you want to be able to pick 0 or the empty string, replace || with //. This requires a recent version of perl (read: not ancient).

The rest looks reasonable. Fixing the stuff I suggested should cut the size a little, and I wouldn't try shortening it further.

Some of the replaced lines are left as comments.

sub getEmailData {
    my $self = shift;

    my $defs = QuickContentFunction::Simple::QuerySearchFieldDefinitions->new();

    my $phParams = decode_json($self->parameters);
    # my @aFields = split(/~/, $phParams->{sFields});
    # my @aCategories = split(/~/, $phParams->{sCategories});
    # my @aValues = split(/~/, $phParams->{sValues});
    # my @aConditions = split(/~/, $phParams->{sConditions});

    my ($aFields, $aCategories, $aValues, $aConditions) = 
      map [ split /~/, $phParams->{$_} ],
      qw(sFields sCategories sValues sConditions);

    my $sSummary = $phParams->{sSummary};
    $sSummary =~ tr|'||d; # s/\'//g;
    my @aSummary = split(/\d/, $sSummary);

    my $phData = { name => $self->name };

    my $mapping = $self->getOperatorMapping();
    # for (my $i = 0; $i < scalar(@aFields); $i++) 
    for my $i (0 .. $#$aFields) {
        my $phFieldInfo = $defs->getFieldHash( $aCategories->[$i], $aFields->[$i]);

        my $value = $aValues->[$i];
        if ($phFieldInfo->{value_displays}) {
            $value = $phFieldInfo->{value_displays}[$value];
        } 
        elsif ($phFieldInfo->{value_keys}) {
            $value = $phFieldInfo->{value_keys}[$value];
        }

        push @{$phData->{conditions}}, {
            field    => $phFieldInfo->{field_display},
            operator => $mapping->{ $phFieldInfo->{field_type} }{ $aConditions->[$i] },
            value    => $value,
            postfix  => $aSummary[$i+1] || undef
        };
    }

    $phData->{mode} = lc($phParams->{sMode});
    if ($self->hasResults()) {
        # $phData->{deals} = \@{decode_json($self->result)};
        $phData->{deals} = decode_json($self->result);
    }

    return $phData;
}