Conditional ListPlot with text recognition

ListPlot[List /@ mydata[[;; , {2, 1}]], BaseStyle -> [email protected], PlotRange -> Full,
 PlotStyle -> Replace[mydata[[;; , -1]], 
                      {"acid n-undecanoic" | "acid salycilic" -> Red, _ -> Green},
                      {1}]
 ]

Here is a simple step-by-step approach.

sorted = Sort @ mydata;
pts = List /@ sorted[[All, ;; 2]];
colors = 
  If[StringMatchQ[#, "acid n-undecanoic" | "acid salycilic"], Red, Green] & /@ 
    sorted[[All, -1]];
ListPlot[pts, PlotStyle -> colors]

Update

The above plot would really be more useful if it had tooltips identifying which acid a point represented on mouse-over. Such tooltips are really easy to add. Here is the code showing how to add them:

Module[{sorted, pts, names, colors},
  sorted = Sort @ myData;
  pts = List /@ sorted[[All, ;; 2]];
  names = sorted[[All, -1]];
  colors = 
    If[StringMatchQ[#, "acid n-undecanoic" | "acid salycilic"], Red, Green] & /@ names;
  ListPlot[Thread[Tooltip[pts, names]], PlotStyle -> colors]]

An alternative using Graphics

acids[data_, choice_] := Module[{points},

  points =
   data /. {a_, b_, c_, d_} :>
     If[Or @@ choice /. s_String :> d == s,
      {Text[d, {b, a - 0.025}], {Red, Point[{b, a}]}},
      {Blue, Point[{b, a}]}];

  Graphics[{PointSize[0.02], points},
   AspectRatio -> 1/GoldenRatio,
   Axes -> True,
   AxesOrigin -> {0, 0.3},
   ImageSize -> 400]]

acids[mydata, {"acid glutaric", "acid acetic", "acid azelaic"}]

An alternative approach is Styleing individual points in the data set and using the styled data set as the input to ListPlot. Define a coloring function:

colorF["acid n-undecanoic" | "acid salycilic"] = Red;
colorF[_] := Green;

styleddata = Style[{#2, #1}, colorF[#4], [email protected]] & @@@ mydata;
ListPlot[styleddata]

Note: We can also use colorF to set the option value for PlotStyle after breaking mydata into Length[mydata] data sets as in Kuba's approach:

ListPlot[List /@ mydata[[All, {2, 1}]], 
         BaseStyle -> [email protected], 
         PlotStyle -> (colorF /@ mydata[[All, -1]])]

Since we do not break the data into individual points or change the ordering of points in the data set while styling, we can use the option Joined -> True directly, when we need to, without additional processing:

ListPlot[styleddata, Joined->True, PlotMarkers->{Automatic, 0}]

Update: A function similar to colorF can be used for labeling select points (Thanks @eldo for raising the bar:)

labelF[a : "acid n-undecanoic" | "acid salycilic"] := a;
labelF[_] := "";
styleddata = Style[Labeled[{#2, #1}, labelF@#4, Below], colorF@#4, [email protected]] & @@@ mydata;
ListPlot[styleddata]