Replace pattern in file with pattern in second file

$ awk '/SETTINGS START/,/SETTINGS END/ {if (FNR==NR) {a=a"\n"$0}} FNR==NR{next}   /SETTINGS START/{print substr(a,2)} /SETTINGS START/,/CUSTOMIZATION SETTINGS END/{next}  1' file2 file1
ANJALI NISHA

// +++ CUSTOMIZATION SETTINGS START +++

WELCOME ALL

// +++ CUSTOMIZATION SETTINGS END +++

PREETI MONA

Explanation

awk implicitly loops through files line by line. In this case, we have it loop through file2 first, then file1.

• /SETTINGS START/,/SETTINGS END/ {if (FNR==NR) {a=a"\n"$0}}

  The settings section from file2 is captured in the variable a.

• FNR==NR{next}

  If we are still reading file2, skip the rest of the commands and jump to the next line of input.

• /SETTINGS START/{print substr(a,2)}

  If we get here, we are processing file1. When we see the start of the settings section, print the string that we have saved in the variable a.

• /SETTINGS START/,/CUSTOMIZATION SETTINGS END/{next}

  If we are in the settings section of file1, skip the rest of the commands and go to the next input line.

• 1

  1 is awk's cryptic shorthand for print the current line. We only get to this statement if we are in file1 but not in the settings section.