current community

your communities

more stack exchange communities

Stack Exchange Inbox Reputation and Badges
tour help
stack overflow careers
Sign up ×
Stack Overflow is a question and answer site for professional and enthusiast programmers. It's 100% free.
up vote 26 down vote favorite
12

I need to find in file word that matches regex pattern. It must to be using awk...

I ONLY want to print word matched with pattern!

So if in line, i have:

xxx yyy zzz

And pattern:

/yyy/

I wonna only get:

yyy

EDIT: thanks to kurumi i managed to write something like this:

awk '{
        for(i=1; i<=NF; i++) {
                tmp=match($i, /[0-9]..?.?[^A-Za-z0-9]/)
                if(tmp) {
                        print $i
                }
        }
}' $1

and this is what i needed :) thanks a lot!

share|improve this question
1  
Here is a manual on regular expressions in awk: informatik.uni-hamburg.de/RZ/software/gnu/utilities/gawk_5.html –  max taldykin Apr 4 '11 at 8:16
1  
i read this, and this is too geeky for me :S –  marverix Apr 4 '11 at 8:17
2  
then I would suggest you to provide a little bit more details of your task. It is too vague. –  max taldykin Apr 4 '11 at 8:20

5 Answers 5

up vote 36 down vote accepted

This is the very basic

awk '/pattern/{ print $0 }' file

ask awk to search for pattern using //, then print out the line, which by default is called a record, denoted by $0. At least read up the documentation.

If you only want to get print out the matched word. 

awk '{for(i=1;i<=NF;i++){ if($i=="yyy"){print $i} } }' file
share|improve this answer
14  
Since print is the default action: awk '/pattern/' file will suffice. –  Johnsyweb Apr 4 '11 at 8:22
9  
@Johnsyweb, yes I do know this fact. To a beginner like marverix, its meant to be more visual. –  kurumi Apr 4 '11 at 8:25
4  
I don't doubt your knowledge. The information may be useful to others finding this answer, however. –  Johnsyweb Apr 4 '11 at 8:42
1  
N.B: @marverix will have to a little more homework to get the for-loop to work if (a) "yyy" is a regular expression and not a straight string and (b) if that "yyy" does not match an entire field within a record. –  Johnsyweb Apr 4 '11 at 9:28
up vote 0 down vote

If Perl is an option, you can try this:

perl -lne 'print $1 if /(regex)/' file
share|improve this answer
up vote 1 down vote

gawk can get the matching part of every line using this as action:

{ if (match($0,/your regexp/,m)) print m[0] }

match(string, regexp [, array]) If array is present, it is cleared, and then the zeroth element of array is set to the entire portion of string matched by regexp. If regexp contains parentheses, the integer-indexed elements of array are set to contain the portion of string matching the corresponding parenthesized subexpression. http://www.gnu.org/software/gawk/manual/gawk.html#String-Functions

share|improve this answer
up vote 4 down vote

If you are only interested in the last line of input and you expect to find only one match (for example a part of the summary line of a shell command), you can also try this very compact code, adopted from Print regexp matches in AWK:

$ echo "xxx yyy zzz" | awk '{match($0,"yyy",a)}END{print a[0]}'
yyy

Or the more complex version with a partial result:

$ echo "xxx=a yyy=b zzz=c" | awk '{match($0,"yyy=([^ ]+)",a)}END{print a[1]}'
b

PS: the awk match() function with three arguments only exists in gawk, not in mawk

share|improve this answer
up vote 45 down vote

It sounds like you are trying to emulate GNU's grep -o behaviour. This will do that providing you only want the first match on each line:

awk 'match($0, /regex/) {
    print substr($0, RSTART, RLENGTH)
}
' file

Here's an example:

% awk 'match($0, /a.t/) {
    print substr($0, RSTART, RLENGTH)
}
' /usr/share/dict/words | head
act
act
act
act
aft
ant
apt
art
art
art

For the rest of your homework, you should look up what each of match, subst RSTART and RLENGTH do in the awk manual.

After that you may wish to extend this to deal with multiple matches on the same line. I can't do all your homework for you :-)

share|improve this answer
    
N.B: To answer that last part, all of the constructs needed are in kurumi's answer and my own. –  Johnsyweb Apr 4 '11 at 10:04
    
Great answer. Just I would like an explanation here in place because I am lazy. But that's why I am using AWK! –  lukas.pukenis Aug 22 '14 at 22:08

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.