current community

more stack exchange communities

Stack Exchange
tour help
careers 2.0
Take the 2-minute tour ×
Stack Overflow is a question and answer site for professional and enthusiast programmers. It's 100% free, no registration required.
up vote 1 down vote favorite

I am writing a file to remove spaces from filenames in a folder and then put the result in a .txt file. I just get a result of "Echo is on." over and over.

This is what I have so far:

@echo ON
SET LOCAL EnableDelayedExpansion
For %%# in (*.*) do (
    SET var=%%~n#
    Set MyVar=%var%
    set MyVar=%MyVar: =%
    echo %MyVar%>>text.txt
)

Can someone tell me whats wrong?

share|improve this question
 
Did you call the batch file echo.bat/cmd ? –  foxidrive Apr 29 '13 at 11:05
add comment

3 Answers

up vote 0 down vote accepted

The reason why you are getting ECHO is on. is because delayed expansion was not used, which caused the value of %var% and %MyVar% to be inserted before the for command is run, and since they were not defined at the start, empty variables were inserted in. When the echo %MyVar%>>text.txt was run, it was interpreted as echo >>text.txt. When echo is run without any arguments, it outputs whether echo is on or off, which is what you get in text.txt.

To fix the problem, you have to do two things:

First, there is something wrong with your second line. There is no space between set and local in setlocal. The second line should be SETLOCAL EnableDelayedExpansion.

Second, to use delayed expansion, you have to replace all %s in each variable with !, like !var! instead of %var%.

End result:

@echo ON
SETLOCAL EnableDelayedExpansion
For %%# in (*.*) do (
    SET var=%%~n#
    Set MyVar=!var!
    set MyVar=!MyVar: =!
    echo !MyVar!>>text.txt
)

You actually do not need to use a temporary variable in this case, you can just do SET MyVar=%%~n# and skip to set MyVar=!MyVar: =!.

share|improve this answer
 
Thank you, works perfectly –  user2313522 Apr 29 '13 at 10:41
 
@user2313522 Added more explanations.. –  user2033427 Apr 29 '13 at 10:43
add comment
up vote 0 down vote

Run the following batch in the folder holding the files to be renamed

    @echo off
    setlocal enabledelayedexpansion
    for %%j in (*.*) do (
    set filename=%%~nj
    set filename=!filename=.=_!
    set filename=!filename= =_!
    if not "!filename!"=="%%~nj" ren "%%j" "!filename!%%~xj"
    )

you just need to add the print to txt

share|improve this answer
 
that just removed all the file names and left the extensions –  user2313522 Apr 29 '13 at 10:37
add comment
up vote 0 down vote

The wrong thing is you've enabled the variable expansion (you wroted it bad...) and also you are not using it, when you use enabledelayedexpansion you need to write the variable names as this: !Variable! instead of this else: %Variable%

But you don't need to use it with this code:

@echo ON
For %%# in (*) do (
    SET "var=%%~n#"
    Call Set "MyVar=%%var: =%%"
    Call echo %%MyVar%%>>text.txt
)
share|improve this answer
 
Call Set "MyVar=%%var: =%%" does not work in a loop. –  foxidrive Apr 29 '13 at 11:07
 
@foxidrive, It works, sorry but... you've tested it before comment?. –  ElektroStudios Apr 29 '13 at 11:08
 
My mistake. It works fine. –  foxidrive Apr 29 '13 at 13:11
 
no problemmmmmm –  ElektroStudios Apr 30 '13 at 2:24
add comment

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.